linux manpages 中文版
{"type":"documentation"}

PERLFAQ9

Section: Perl Programmers Reference Guide (7)
Updated: 2003-11-25
Index Return to Main Contents
 

NAME

perlfaq9 - 网络 (2003/01/31 17:36:57 )  

DESCRIPTION 描述

网络通信，互联网以及少量有关 web 的内容

What is the correct form of response from a CGI script?

(Alan Flavell <flavell+www@a5.ph.gla.ac.uk> answers...)

The Common Gateway Interface (CGI) specifies a software interface between a program (``CGI script'') and a web server (HTTPD). It is not specific to Perl, and has its own FAQs and tutorials, and usenet group, comp.infosystems.www.authoring.cgi

The original CGI specification is at: http://hoohoo.ncsa.uiuc.edu/cgi/

Current best-practice RFC draft at: http://CGI-Spec.Golux.Com/

Other relevant documentation listed in: http://www.perl.org/CGI_MetaFAQ.html

These Perl FAQs very selectively cover some CGI issues. However, Perl programmers are strongly advised to use the CGI.pm module, to take care of the details for them.

The similarity between CGI response headers (defined in the CGI specification) and HTTP response headers (defined in the HTTP specification, RFC2616) is intentional, but can sometimes be confusing.

The CGI specification defines two kinds of script: the ``Parsed Header'' script, and the ``Non Parsed Header'' (NPH) script. Check your server documentation to see what it supports. ``Parsed Header'' scripts are simpler in various respects. The CGI specification allows any of the usual newline representations in the CGI response (it's the server's job to create an accurate HTTP response based on it). So ``\n'' written in text mode is technically correct, and recommended. NPH scripts are more tricky: they must put out a complete and accurate set of HTTP transaction response headers; the HTTP specification calls for records to be terminated with carriage-return and line-feed, i.e ASCII \015\012 written in binary mode.

Using CGI.pm gives excellent platform independence, including EBCDIC systems. CGI.pm selects an appropriate newline representation ($CGI::CRLF) and sets binmode as appropriate.

我的 CGI 脚本从命令行执行正常，但是在浏览器中不行 (500 Server Error)。

可能有很多事错了。可以仔细阅读 ``Troubleshooting Perl CGI scripts'' guide, 位置是 

        http://www.perl.org/troubleshooting_CGI.html

如果接下来，你能证明你已阅读了 FAQ 并且你的问题不是那么简单，非叁言两语即可回答的话，那麽您 post到 comp.infosystems.www.authoring.cgi上（如果是有关 HTTP 、 HTML ，或 CGI通信协定）的问题可能也会得到口气和缓而有用的答覆。表面上看似 Perl，但骨子里是 CGI之类的问题，如果 post到 comp.lang.perl.misc人家可能就不会这麽乐意地接受了。

几个实用的 FAQ，相关文档和查错向导列在 CGI Meta FAQ 中： 

        http://www.perl.org/CGI_MetaFAQ.html

如何从 CGI 程序中得到好一点的错误提示？

Use the CGI::Carp module. It replaces "warn" and "die", plus the normal Carp modules "carp", "croak", and "confess" functions with more verbose and safer versions. It still sends them to the normal server error log. 

    use CGI::Carp;
    warn "This is a complaint";
    die "But this one is serious";

The following use of CGI::Carp also redirects errors to a file of your choice, placed in a BEGIN block to catch compile-time warnings as well: 

    BEGIN {
        use CGI::Carp qw(carpout);
        open(LOG, ">>/var/local/cgi-logs/mycgi-log")
            or die "Unable to append to mycgi-log: $!\n";
        carpout(*LOG);
    }

You can even arrange for fatal errors to go back to the client browser, which is nice for your own debugging, but might confuse the end user. 

    use CGI::Carp qw(fatalsToBrowser);
    die "Bad error here";

Even if the error happens before you get the HTTP header out, the module will try to take care of this to avoid the dreaded server 500 errors. Normal warnings still go out to the server error log (or wherever you've sent them with "carpout") with the application name and date stamp prepended.

如何将字符串中的 HTML 删除？

最正确（尽管不是最快）的方法是使用 HTML::Parse模组（可由 CPAN取得，是所有写 Web程式者必备的 libwww-perl 套件的一部分）。另一中最正确的办法是使用 HTML::FormatText，它不仅删除了 HTML，同时也试图对结果文本进行简单的格式化。

许多人尝试用简陋的正规表示式来解决这个问题，譬如说像 "s/<.*?>//g"，但这个式子在很多情况下会失败，因为要处理的字串可能会跨越断行字元，也可能含有被 quote【跳脱】的箭头号，或有 HTML comment出现；再加上一些疏忽，譬如，人们常忘了转换如 < 的 entities（跳脱字 元"&lt;"）。

以下这个「简陋」的方法对大多数的档案都有效： 

    #!/usr/bin/perl -p0777
    s/<(?:[^>'"]*|(['"]).*?\1)*>//gs

如果您想要更完整的解法，请看叁部曲的 striphtml 程式， http://www.cpan.org/authors/Tom_Christiansen/scripts/striphtml.gz .

Here are some tricky cases that you should think about when picking a solution: 

    <IMG SRC = "foo.gif" ALT = "A > B">



    <IMG SRC = "foo.gif"
         ALT = "A > B">



    <!-- <A comment> -->



    <script>if (a<b && a>c)</script>



    <# Just data #>



    <![INCLUDE CDATA [ >>>>>>>>>>>> ]]>

If HTML comments include other tags, those solutions would also break on text like this: 

    <!-- This section commented out.
        <B>You can't see me!</B>
    -->

如何萃取 URL?

可以简单地从 HTML 中得到所有种类的 URL，只要使用 "HTML::SimpleLinkExtor" 模块，它可以处理锚，图像，对象，桢，其他包含 URL 的标签。如果需要更复杂的东西，可以创建 "HTML::LinkExtor" 的子类或使用 "HTML::Parser". 你甚至可以用 "HTML::SimpleLinkExtor" 作为范例，来书写适合你特殊需要的程序。

You can use URI::Find to extract URLs from an arbitrary text document.

Less complete solutions involving regular expressions can save you a lot of processing time if you know that the input is simple. One solution from Tom Christiansen runs 100 times faster than most module based approaches but only extracts URLs from anchors where the first attribute is HREF and there are no other attributes. 

        #!/usr/bin/perl -n00
        # qxurl - tchrist@perl.com
        print "$2\n" while m{
            < \s*
              A \s+ HREF \s* = \s* (["']) (.*?) \1
            \s* >
        }gsix;

如何从用户的机器上下载文件？如何打开其他机器上的文件？

In this case, download means to use the file upload feature of HTML forms. You allow the web surfer to specify a file to send to your web server. To you it looks like a download, and to the user it looks like an upload. No matter what you call it, you do it with what's known as multipart/form-data encoding. The CGI.pm module (which comes with Perl as part of the Standard Library) supports this in the start_multipart_form() method, which isn't the same as the startform() method.

See the section in the CGI.pm documentation on file uploads for code examples and details.

如何在 HTML 添加一个弹出菜单?

用 <SELECT> 和 <OPTION>这两个标签。 CGI.pm模组（可由 CPAN取得）对这个 widget【此指跳出式选单这个介面成分】还有许多其他的介面成分都有支援【即有制作动态标签的函式】，其中有些是以巧妙模拟的方 式达成。

如何获取 HTML 文件?

有一个方法是，如果您的系统上装有 lynx一类的文字模式的 HTML浏览器的话，那麽可以这麽做： 

    $html_code = `lynx -source $url`;
    $text_data = `lynx -dump $url`;

收录在 CPAN里的 libwww-perl (LWP)模组则提供了更强的方法来做这件事。它不但可钻过 proxies，而且也不需要 lynx： 

    # simplest version
    use LWP::Simple;
    $content = get($URL);



    # or print HTML from a URL
    use LWP::Simple;
    getprint "http://www.linpro.no/lwp/";



    # or print ASCII from HTML from a URL
    # also need HTML-Tree package from CPAN
    use LWP::Simple;
    use HTML::Parser;
    use HTML::FormatText;
    my ($html, $ascii);
    $html = get("http://www.perl.com/");
    defined $html
        or die "Can't fetch HTML from http://www.perl.com/";
    $ascii = HTML::FormatText->new->format(parse_html($html));
    print $ascii;

如何根据提交的内容自动生成一个 HTML ?

If you're submitting values using the GET method, create a URL and encode the form using the "query_form" method: 

    use LWP::Simple;
    use URI::URL;



    my $url = url('http://www.perl.com/cgi-bin/cpan_mod');
    $url->query_form(module => 'DB_File', readme => 1);
    $content = get($url);

If you're using the POST method, create your own user agent and encode the content appropriately. 

    use HTTP::Request::Common qw(POST);
    use LWP::UserAgent;



    $ua = LWP::UserAgent->new();
    my $req = POST 'http://www.perl.com/cgi-bin/cpan_mod',
                   [ module => 'DB_File', readme => 1 ];
    $content = $ua->request($req)->as_string;

如何解码或创建 web 中的 %-encoding?

If you are writing a CGI script, you should be using the CGI.pm module that comes with perl, or some other equivalent module. The CGI module automatically decodes queries for you, and provides an escape() function to handle encoding.

The best source of detailed information on URI encoding is RFC 2396. Basically, the following substitutions do it: 

    s/([^\w()'*~!.-])/sprintf '%%%02x', ord $1/eg;   # encode



    s/%([A-Fa-f\d]{2})/chr hex $1/eg;            # decode

However, you should only apply them to individual URI components, not the entire URI, otherwise you'll lose information and generally mess things up. If that didn't explain it, don't worry. Just go read section 2 of the RFC, it's probably the best explanation there is.

RFC 2396 also contains a lot of other useful information, including a regexp for breaking any arbitrary URI into components (Appendix B).

如何重定向到其他页面？

Specify the complete URL of the destination (even if it is on the same server). This is one of the two different kinds of CGI ``Location:'' responses which are defined in the CGI specification for a Parsed Headers script. The other kind (an absolute URLpath) is resolved internally to the server without any HTTP redirection. The CGI specifications do not allow relative URLs in either case.

Use of CGI.pm is strongly recommended. This example shows redirection with a complete URL. This redirection is handled by the web browser. 

      use CGI qw/:standard/;



      my $url = 'http://www.cpan.org/';
      print redirect($url);

This example shows a redirection with an absolute URLpath. This redirection is handled by the local web server. 

      my $url = '/CPAN/index.html';
      print redirect($url);

But if coded directly, it could be as follows (the final ``\n'' is shown separately, for clarity), using either a complete URL or an absolute URLpath. 

      print "Location: $url\n";   # CGI response header
      print "\n";                 # end of headers

如何为我的网页加上密码？

要启用 web 服务器的验证，你需要配置你的 web 服务器，不同的服务器有不同的方法---apache 与 iPlanet 不同，后者又与 IIS 不同。从你的 web 服务器的文档中查找特定服务器的配置细节。

如何用 Perl 修改我的 .htpasswd 和 .htgroup 文件?

HTTPD::UserAdmin 和 HTTPD::GroupAdmin 等模组为这些档案提供了统一的物件导向介面，尽管这些档案可能以各种不同的格式储存。这些资料库可能是纯文字格式、 dbm、Berkeley DB或任何 DBI相容的资料库驱动程式 (drivers)。 HTTPD::UserAdmin支援`Basic' 和 `Digest'这两个认证模式所用的档案。以下是 一例： 

    use HTTPD::UserAdmin ();
    HTTPD::UserAdmin
          ->new(DB => "/foo/.htpasswd")
          ->add($username => $password);

如何确保用户不会在表单中输入使我的 CGI 脚本作坏事的值？

阅读 CGI Meta FAQ 列出的安全索引 

        http://www.perl.org/CGI_MetaFAQ.html

如何解释一个邮件头？

要使用一个快速的方法，可以这样使用 perlfunc 中的 ``split'' 函数： 

    $/ = '';
    $header = <MSG>;
    $header =~ s/\n\s+/ /g;      # 将延续行合并成单行
    %head = ( UNIX_FROM_LINE, split /^([-\w]+):\s*/m, $header );

但是，如果您若想保留所有 Received栏位资料的话【因 Received 栏位通常不止一个】，这个解法便不太行了。一个完整的解法是使用收录在 CPAN的 Mail::Header 模组（ MailTools 套件的一部分）。

如何解码一个 CGI 表单？

使用标准模块，应该是 CGI.pm。没有理由去尝试手动去做！

你大概都看过一大堆从 STDIN 读取与 $ENV{CONTENT_LENGTH} 长度相同的字节，或者获取 $ENV{QUERY_STRING} 来解码 GET。这些程序都非常糟糕。他们仅在某些时候工作。他们通常不检查 read() 的返回值，这是主要的错误。他们不处理 HEAD 请求。他们不处理文件上载时的多成分表单。They don't deal with GET/POST combinations where query fields are in more than one place. They don't deal with keywords in the query string.

In short, they're bad hacks. Resist them at all costs. Please do not be tempted to reinvent the wheel. Instead, use the CGI.pm or CGI_Lite.pm (available from CPAN), or if you're trapped in the module-free land of perl1 .. perl4, you might look into cgi-lib.pl (available from http://cgi-lib.stanford.edu/cgi-lib/ ).

Make sure you know whether to use a GET or a POST in your form. GETs should only be used for something that doesn't update the server. Otherwise you can get mangled databases and repeated feedback mail messages. The fancy word for this is ``idempotency''. This simply means that there should be no difference between making a GET request for a particular URL once or multiple times. This is because the HTTP protocol definition says that a GET request may be cached by the browser, or server, or an intervening proxy. POST requests cannot be cached, because each request is independent and matters. Typically, POST requests change or depend on state on the server (query or update a database, send mail, or purchase a computer).

如何检测一个有效的邮件地址？

没有办法。至少，没有可行的办法。

如果没有寄封信到一个位址去试试看它会不会弹回来（即使是这麽做您还得面对停顿的问题），您是无法确定一个位址是否真的存在的。即使您套用 email 标头的标准规格来做检查的依据，您还是有可能会遇到问题，因为有些送得到的位址并不 符合 RFC-822（电子邮件标头的标准）的规定，但有些符合标准的位址却无法投 递。

You can use the Email::Valid or RFC::RFC822::Address which check the format of the address, although they cannot actually tell you if it is a deliverable address (i.e. that mail to the address will not bounce). Modules like Mail::CheckUser and Mail::EXPN try to interact with the domain name system or particular mail servers to learn even more, but their methods do not work everywhere---especially for security conscious administrators.

许多人试图用一个简单的正规表示式，例如 "/^[\w.-]+\@(?:[\w-]+\.)+\w+$/" 来消除一些通常是无效的 email 位址。不过，这样做也把很多合格的位址给一起滤掉了，而且对测试一个位址有没有希望投递成功完全没有帮助，所以在此建议大家不要这麽做；不过您可以看看： http://www.cpan.org/authors/Tom_Christiansen/scripts/ckaddr.gz , 这个 script真的彻底地依据所有的 RFC规定来做检验（除了内嵌式 comments外）,同时会排除一些您可能不会想送信去的位址（如 Bill Clinton【美国总统】或您的 postmaster），然後它会确定位址中的主机名称可在 DNS中找得到。这个 script 跑起来不是很快，但至少有效。

Our best advice for verifying a person's mail address is to have them enter their address twice, just as you normally do to change a password. This usually weeds out typos. If both versions match, send mail to that address with a personal message that looks somewhat like: 

    Dear someuser@host.com,



    Please confirm the mail address you gave us Wed May  6 09:38:41
    MDT 1998 by replying to this message.  Include the string
    "Rumpelstiltskin" in that reply, but spelled in reverse; that is,
    start with "Nik...".  Once this is done, your confirmed address will
    be entered into our records.

If you get the message back and they've followed your directions, you can be reasonably assured that it's real.

A related strategy that's less open to forgery is to give them a PIN (personal ID number). Record the address and PIN (best that it be a random one) for later processing. In the mail you send, ask them to include the PIN in their reply. But if it bounces, or the message is included via a ``vacation'' script, it'll be there anyway. So it's best to ask them to mail back a slight alteration of the PIN, such as with the characters reversed, one added or subtracted to each digit, etc.

如何解码一个 MIME/BASE64 字符串?

MIME-tools套件（可自 CPAN取得）不但可处理这个问题而且有许多其他的功能。有了这个套件，解 BASE64码就变得像这麽容易： 

    use MIME::Base64;
    $decoded = decode_base64($encoded);

The MIME-Tools package (available from CPAN) supports extraction with decoding of BASE64 encoded attachments and content directly from email messages.

一个比较直接的解法是先做一点简单的转译，然後使用 unpack()这个函数的 ``u'' 格式： 

    tr#A-Za-z0-9+/##cd;                   # remove non-base64 chars
    tr#A-Za-z0-9+/# -_#;                  # convert to uuencoded format
    $len = pack("c", 32 + 0.75*length);   # compute length byte
    print unpack("u", $len . $_);         # uudecode and print

如何返回用户的邮件地址？

On systems that support getpwuid, the $< variable, and the Sys::Hostname module (which is part of the standard perl distribution), you can probably try using something like this: 

    use Sys::Hostname;
    $address = sprintf('%s@%s', scalar getpwuid($<), hostname);

Company policies on mail address can mean that this generates addresses that the company's mail system will not accept, so you should ask for users' mail addresses when this matters. Furthermore, not all systems on which Perl runs are so forthcoming with this information as is Unix.

The Mail::Util module from CPAN (part of the MailTools package) provides a mailaddress() function that tries to guess the mail address of the user. It makes a more intelligent guess than the code above, using information given when the module was installed, but it could still be incorrect. Again, the best way is often just to ask the user.

如何发邮件？

Use the "sendmail" program directly: 

    open(SENDMAIL, "|/usr/lib/sendmail -oi -t -odq")
                        or die "Can't fork for sendmail: $!\n";
    print SENDMAIL <<"EOF";
    From: User Originating Mail <me\@host>
    To: Final Destination <you\@otherhost>
    Subject: A relevant subject line



    Body of the message goes here after the blank line
    in as many lines as you like.
    EOF
    close(SENDMAIL)     or warn "sendmail didn't close nicely";

The -oi option prevents sendmail from interpreting a line consisting of a single dot as ``end of message''. The -t option says to use the headers to decide who to send the message to, and -odq says to put the message into the queue. This last option means your message won't be immediately delivered, so leave it out if you want immediate delivery.

Alternate, less convenient approaches include calling mail (sometimes called mailx) directly or simply opening up port 25 have having an intimate conversation between just you and the remote SMTP daemon, probably sendmail.

Or you might be able use the CPAN module Mail::Mailer: 

    use Mail::Mailer;



    $mailer = Mail::Mailer->new();
    $mailer->open({ From    => $from_address,
                    To      => $to_address,
                    Subject => $subject,
                  })
        or die "Can't open: $!\n";
    print $mailer $body;
    $mailer->close();

The Mail::Internet module uses Net::SMTP which is less Unix-centric than Mail::Mailer, but less reliable. Avoid raw SMTP commands. There are many reasons to use a mail transport agent like sendmail. These include queuing, MX records, and security.

如何使用 MIME 来为邮件消息增加附件？

This answer is extracted directly from the MIME::Lite documentation. Create a multipart message (i.e., one with attachments). 

    use MIME::Lite;



    ### Create a new multipart message:
    $msg = MIME::Lite->new(
                 From    =>'me@myhost.com',
                 To      =>'you@yourhost.com',
                 Cc      =>'some@other.com, some@more.com',
                 Subject =>'A message with 2 parts...',
                 Type    =>'multipart/mixed'
                 );



    ### Add parts (each "attach" has same arguments as "new"):
    $msg->attach(Type     =>'TEXT',
                 Data     =>"Here's the GIF file you wanted"
                 );
    $msg->attach(Type     =>'image/gif',
                 Path     =>'aaa000123.gif',
                 Filename =>'logo.gif'
                 );



    $text = $msg->as_string;

MIME::Lite also includes a method for sending these things. 

    $msg->send;

This defaults to using sendmail but can be customized to use SMTP via Net::SMTP.

如何读邮件？

While you could use the Mail::Folder module from CPAN (part of the MailFolder package) or the Mail::Internet module from CPAN (part of the MailTools package), often a module is overkill. Here's a mail sorter. 

    #!/usr/bin/perl



    my(@msgs, @sub);
    my $msgno = -1;
    $/ = '';                    # paragraph reads
    while (<>) {
        if (/^From /m) {
            /^Subject:\s*(?:Re:\s*)*(.*)/mi;
            $sub[++$msgno] = lc($1) || '';
        }
        $msgs[$msgno] .= $_;
    }
    for my $i (sort { $sub[$a] cmp $sub[$b] || $a <=> $b } (0 .. $#msgs)) {
        print $msgs[$i];
    }

Or more succinctly, 

    #!/usr/bin/perl -n00
    # bysub2 - awkish sort-by-subject
    BEGIN { $msgno = -1 }
    $sub[++$msgno] = (/^Subject:\s*(?:Re:\s*)*(.*)/mi)[0] if /^From/m;
    $msg[$msgno] .= $_;
    END { print @msg[ sort { $sub[$a] cmp $sub[$b] || $a <=> $b } (0 .. $#msg) ] }

如何找到我的主机名/域名/IP 地址？

长久以来许多 code都很草率地直接呼叫 `hostname` 这个程式来取得主机名。虽然这麽做很方便，但也同时增加了移植到其他平台上的困难。这是一个很典型的例子，在方便和可移植性之间作抉择，不论选哪一边，必须付出一些牺牲和代价。

Sys::Hostname这个模组（标准 perl发行的一部分）可用来取得机器的名字，然後您便可利用 gethostbyname()这个系统呼叫来找出该机的 IP位址了（假定您的 DNS 运作正常）。 

    use Socket;
    use Sys::Hostname;
    my $host = hostname();
    my $addr = inet_ntoa(scalar gethostbyname($host || 'localhost'));

至少在 Unix 底下，取得 DNS网域名最简单的方法大概要算是直接从 /etc/resolv.conf 这个档案里面找。当然，这麽做的前提是 resolv.conf 这个档案的设定必须照惯例的格式，还有就是这个档案必先存在才行。

(Perl在非 Unix系统下尚需要一有效的方法来测出机器和网域名)

如何获取一篇新闻文章或活动的新闻组？

使用 Net::NNTP或 News::NNTPClient模组，两者皆可自 CPAN下载。这些模组让抓群组名录这类的差事变得这麽容易： 

    perl -MNews::NNTPClient
      -e 'print News::NNTPClient->new->list("newsgroups")'

如何获取/上传一个 FTP 文件?

LWP::Simple模组（可自 CPAN下载）可以抓，但不能上传档案。 Net::FTP模组（也可自 CPAN下载）虽比较复杂，但可用来上传、也能抓档案。

如何进行远程过程调用 RPC ?

模块 DCE::RPC 正在开发中 (但是还不可用)，将成为 DCE-Perl 包 (可以从 CPAN 下载) 的一部分。rpcgen 套件，可以从 CPAN/authors/id/JAKE/ 找到，是一个 RPC 存根生成器，包含一个 RPC::ONC 模块。  

AUTHOR AND COPYRIGHT

Copyright (c) 1997-2002 Tom Christiansen and Nathan Torkington. All rights reserved.

This documentation is free; you can redistribute it and/or modify it under the same terms as Perl itself.

Irrespective of its distribution, all code examples in this file are hereby placed into the public domain. You are permitted and encouraged to use this code in your own programs for fun or for profit as you see fit. A simple comment in the code giving credit would be courteous but is not required.  

译者

萧百龄，两只老虎工作室

 

Index

NAME
DESCRIPTION 描述
AUTHOR AND COPYRIGHT
译者
This document was created by man2html, using the manual pages.
Time: 13:12:52 GMT, December 24, 2015